@echo off

net session >nul 2>&1
if '%errorlevel%' NEQ '0' (
    echo Administrator-Rechte sind erforderlich. Fordere Administrator-Rechte an...
    goto UACPrompt
) else (
    goto gotAdmin
)

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params= %*
    echo UAC.ShellExecute "cmd.exe", "/c ""%~s0"" %params:"=""%", "", "runas", 1 >> "%temp%\getadmin.vbs"
    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    pushd "%CD%"
    CD /D "%~dp0"
    echo Windows Dienst MMI-data4doc-UpdateService wird installiert...
    net session >nul 2>&1
    if %errorLevel% == 0 (
	    echo Installing MMI-data4doc-UpdateService
	    sc create "MMI-data4doc-UpdateService" binpath= "%~dp0UpdateService.exe" start= auto
        sc description "MMI-data4doc-UpdateService" "MMI-data4doc-UpdateService aktualisiert data4doc auf den neusten Stand."
        call "%~dp0StartService.bat"
    ) else (
        echo Fehler! Es sind Administrator-Rechte erforderlich um den Windows Dienst MMI-data4doc-UpdateService zu installieren.
    )